Zur Etikette beim E-Mail-Verkehr gehört für mich (wenn es sich nicht gerade um einen "Pseudo-Chat" handelt), die E-Mail mit einer Anrede ("Hallo Xaver") zu beginnen und mit einem Schluss-MfG ("Gruß – Erwin") zu beenden.
Je nachdem, ob man per Du ist natürlich mit Vornamen oder Nachnamen.
Besonders in der Firma kam mir bei täglich dutzenden E-Mails mal die Frage "kann ich mir das Getippe nicht sparen und wieso muss ich mir bei 'Herr Kulczynski' immer wieder auf's Neue einen abbrechen?" auf.
Es sind die kleinen Hacks, die einem das Tagesgeschäft erleichtern.
Anbei eine Anleitung, wie Anrede und Schluss-Gruß gleich in die E-Mail rein geschrieben werden, wenn man eine E-Mail mittels Apfel-R beantwortet.
Läuft bei mir unter Entourage, sollte aber auch mit dem neueren Outlook funktionieren.
Mein Apple-Skript
set foermlich_m to {"Max Mustermann", "Xaver Schrottburger"}
set duz_domains to {"apfel-z.net", "gmail.com"}
set keine_anrede to {"Edgar Dauertipper", "Mathilde Chatterley"}
set mein_name to {"Ralf", "Schnitzelberger"}
tell application "Microsoft Entourage" -- Oder je nachdem "Outlook"
-- Aktuell ausgewählte Nachricht(en)
set selectedMessages to current messages
-- Benutzer warnen und Vorgang beenden, wenn keine Nachrichten ausgewählt sind
if selectedMessages is {} then
display dialog "Bitte wählen Sie zuerst eine Nachricht aus, bevor Sie dieses Skript ausführen." with icon 1
return
end if
repeat with theMessage in selectedMessages
set theName to display name of sender of theMessage
set theAddr to address of sender of theMessage
set theAnrede to ""
set newMessage to reply to theMessage
-- Hallo Frau <Nachname>
if theName is in foermlich_f then
set theAnrede to do shell script "perl -e '$name=\"" & theName & "\"; $name =~ m/(\\w*),? (\\w*)/; print $2;'"
set theAnrede to "Frau " & theAnrede
set myName to (item 1 of mein_name) & " " & (item 2 of mein_name)
end if
-- Hallo Herr <Nachname>
if theName is in foermlich_m then
set theAnrede to do shell script "perl -e '$name=\"" & theName & "\"; $name =~ m/(\\w*),? (\\w*)/; print $2;'"
set theAnrede to "Herr " & theAnrede
set myName to (item 1 of mein_name) & " " & (item 2 of mein_name)
end if
-- Hallo <Vorname>
if theAnrede is "" then
-- Domain prüfen, von der die E-Mail stammt
set oldDelimiters to AppleScript's text item delimiters
set AppleScript's text item delimiters to "@"
set theDomainName to every text item of theAddr
set AppleScript's text item delimiters to oldDelimiters
if (item 2 of theDomainName) is in duz_domains then
-- Dann mal an den Vornamen senden...
set theAnrede to do shell script "perl -e '$name=\"" & theName & "\"; $name =~ m/(\\w*),? (\\w*)/; print $1;'"
set myName to (item 1 of mein_name)
end if
end if
-- In E-Mail einfügen
if theName is not in keine_anrede and theAnrede is not "" then
set selection to "Hallo " & theAnrede & ",
Gruß
" & myName
end if
end repeat
end tell
tell application "System Events"
tell process "Microsoft Entourage"
keystroke (ASCII character 30)
keystroke (ASCII character 30)
keystroke (ASCII character 30)
end tell
end tell
Also was läuft hier ab...?
- Im E-Mail-Client ist eine E-Mail, die beantwortet werden soll, ausgewählt
- Das Skript prüft Namen und Adresse des Absenders
- Ist der Name des Absenders in der Liste foermlich_f, wird "Hallo Frau
" als Anrede verwendet - Ist der Name des Absenders in der Liste foermlich_m, wird "Hallo Herr
" als Anrede verwendet - Ist die Domain der E-Mail-Adresse des Absenders nicht in der Liste der duz_domains (bei Kunden wollen wir uns ja etwas mehr Mühe geben) oder ist der Name des Absenders in der Liste keine_anrede, wird nichts automatisch in die neue E-Mail geschrieben
- Ansonsten wird "Hallo
" als Anrede verwendet
Je nachdem wird noch ein "Gruß Ralf" oder "Gruß Ralf Schnitzelberger" (Vorname oder Vorname und Nachname von mein_name ) hintendran angefügt und der Cursor zwischen "Hallo" und "Gruß" gesetzt, so dass die fröhliche Texterei beginnen kann.
Nahtlose Integration
Das Skript muss im Verzeichnis ~/Dokumente/Microsoft-Benutzerdaten/Entourage Script Menu Items abgelegt werden, so dass es im Entourage-Skriptmenü auftaucht.
In meinem Beispiel lautet die Skript-Datei Schnell antworten.scpt.
Jetzt biegen wir noch den Standard-Tastaturbefehl Apfel-R um, so dass er nicht die Entourage-interne Funktion Nachricht > Antworten, sondern das Skript auslöst.
Das geht recht einfach über Systemeinstellungen > Tastatur > Tastaturkurzbefehle > Kurzbefehle für ProgrammeMit dem + -Button einen neuen Kurzbefehl hinzufügen, "Microsoft Entourage" unter "Programme" wählen, bei Menü den Namen des Skriptes (ohne Endung .scpt; so wie es im Skript-Menü von Entourage auftaucht) eingeben und als Tastaturkurzbefehl Apfel-R.
Zurück in Entourage sollte künftig bei dem Tastenkürzel Apfel-R das Skript ausgeführt werden – je nachdem mit eingefügter Anrede – statt einfach nur eine neue E-Mail-Antwort geöffnet werden.
Erstellt am: 02.12.2015 unter den Kategorien Aufgebohrt . | Kommentieren |