Das Tastenkürzel Apfel-N öffnet seit der Einführung von MacOS X im Finder ein neues Fenster. Was in so einem neuen Fenster angezeigt werden soll, lässt sich ganz praktisch im Voreinstellungs-Dialog des Finders einstellen (siehe Bild rechts).

Doch eine eine wirklich hilfreiche Einstellungsmöglichkeit fehlt meiner Ansicht nach: Ein neu geöffnetes Fenster sollte am liebsten den selben Ordnerinhalt darstellen, wie das gerade im Vordergrund befindliche Fenster.
Denn meistens will man noch ein zweites Fenster mit einem Unter- oder Ãœber-Ordner auf dem Bildschirm haben und sich dann nicht nochmals ganz neu durch das Dateisystem hangeln.

Ich habe mir bei diesem Problem von meinem Lieblings-Hotkey-Manager Butler helfen lassen.

In Butler habe ich einen neuen AppleSkript-Eintrag mit folgendem Inhalt hinzugefügt und diesen nur für das Programm "Finder" mit dem Hotkey Apfel-N versehen.

tell application "Finder"
  try
    set t to target of Finder window 1
  on error
    set t to folder "apfelz" of folder "Users" of startup disk of application "Finder"
  end try
  --set w to make new Finder window
  --set target of w to t
  tell (make new Finder window to t) to set {toolbar visible} to {true}
end tell

apfelz ist durch den jeweiligen eigenen kurzen Benutzernamen zu ersetzen. Somit wird als Fallback der Home-Ordner geöffnet, sollte im Finder kein Fenster geöffnet sein).
Die beiden ausskommentierten Zeilen -- hatten bei mir bis MacOS X 10.9 funktioniert. Allerdings waren nach einem Update die neuen Fenster immer ohne Sidebar (obwohl ein "manuell" erstelltes neues Fenster im Finde sehr wohl eine Sidebar hat), so musste ich den Code etwas umschreiben, damit die Sidebar explizit eingeschaltet wird.

Damit sich dieses Tastenkürzel nicht mit dem nativen Finder-Tastenkürzel beißt, legen wir jenes einfach um.
Dazu unter Systemeinstellungen > Tastatur > Tastaturkurzbefehle > Kurzbefehle für Programme ein neues Tastenkürzel für den Menüeintrag "Neues Fenster" im Programm "Finder" hinzufügen und mit etwas belegen, was sonst nicht verwendet wird (im Beispiel rechts Apfel+Shift+Umschalt+N).
 

Ähnlich funktioniert es mit neuen Tabs...allerdings habe ich einen neuen Finder-Tab nur etwas unschön mit Hilfe der System Events hinbekommen.

tell application "Finder"
  try
    set t to target of Finder window 1
  on error
    set t to folder "apfelz" of folder "Users" of startup disk of application "Finder"
  end try

  -- Neuer Tab mit Hilfe der System Events
  tell application "System Events" to tell application process "Finder"
    set frontmost to true
    tell front menu bar to tell menu "Ablage" to tell menu item "Neuer Tab"
      perform action "AXPress"
    end tell
  end tell
 
  tell application "Finder" to set target of Finder window 1 to t
end tell